엑셀 숫자나 날짜를 이용한 IF문 활용

Excel 수식 : 두 숫자 사이

지정된 숫자가 지정한 두 숫자 사이에 있는지 테스트하려면 두 개의 논리 테스트와 함께 AND 함수를 사용합니다.

• >보다 큼 연산자를 사용하여 값이 작은 숫자보다 큰지 확인합니다.
• 보다 작음(<) 연산자를 사용하여 값이 큰 숫자보다 작은지 확인합니다.

일반적인 If between 공식은 다음과 같습니다.

AND(value > smaller_number, value < larger_number)

경계 값을 포함하려면 크거나 같음(>=) 및 작거나 같음(<=) 연산자를 사용합니다.

AND(value >= smaller_number, value <= larger_number)

예를 들어, 경계 값을 포함하지 않고 A2의 숫자가 10에서 20 사이에 있는지 확인하려면 B2의 수식을 복사하면 다음과 같습니다.

=AND(A2>10, A2<20)

 

임계값을 포함하여 A2가 10에서 20 사이인지 확인하기 위해 C2의 수식은 다음 형식을 취합니다.

=AND(A2>=10, A2<=20)

 

두 경우 모두 테스트된 숫자가 10에서 20 사이이면 부울 값 TRUE이고, 그렇지 않으면 FALSE입니다.

 

두 숫자 사이에 있을경우 

숫자가 두 값 사이에 있는 경우 사용자 지정 값을 반환하려면 IF 함수의 논리 테스트에 AND 수식을 배치합니다.

예를 들어 A2의 숫자가 10에서 20 사이이면 "Yes"를 반환하고, 그렇지 않으면 "No"를 반환하려면 다음 IF 문 중 하나를 사용합니다.

 

10에서 20 사이인 경우:

=IF(AND(A2>10, A2<20), "Yes", "No")

 

경계를 포함하여 10에서 20 사이인 경우:

=IF(AND(A2>=10, A2<=20), "Yes", "No")

 

A 열에 값 집합이 있고 같은 행의 B 열과 C 열의 숫자 사이에 어떤 값이 있는지 알고 싶다고 가정합니다. 더 작은 숫자가 항상 B 열에 있고 더 큰 숫자가 C 열에 있다고 가정하면 다음 수식을 사용하여 작업을 수행할 수 있습니다.

=IF(AND(A2>B2, A2<C2), "Yes", "No")

 

경계 포함:

=IF(AND(A2>=B2, A2<=C2), "Yes", "No")

 

다음은 TRUE인 경우 값 자체, FALSE인 경우 일부 텍스트 또는 빈 문자열을 반환하는 If between 문의 변형입니다.

=IF(AND(A2>10, A2<20), A2, "Invalid")

 

경계 포함:

=IF(AND(A2>=10, A2<=20), A2, "Invalid")

 

경계 값이 다른 열에 있는 경우

비교하는 더 작은 숫자와 더 큰 숫자가 다른 열에 나타날 수 있는 경우(즉, 숫자 1이 항상 숫자 2보다 작은 것은 아님) 약간 더 복잡한 버전의 수식을 사용합니다.

AND(value > MIN(num1, num2), value < MAX(num1, num2))

여기서는 먼저 목표값이 MIN 함수에서 반환된 두 숫자 중 작은 값보다 높은지 테스트한 다음 MAX 함수에서 반환된 두 숫자 중 더 큰보다 큰지 확인합니다.

 

임계값 번호를 포함하려면 다음과 같이 논리를 조정합니다.

AND(value >= MIN(num1, num2), value <= MAX(num1, num2))

 

예를 들어 A2의 숫자가 B2와 C2의 두 숫자 사이에 있는지 확인하려면 다음 공식 중 하나를 사용합니다.

경계 제외:

=AND(A2>MIN(B2, C2), A2<MAX(B2, C2))

 

경계 포함:

=AND(A2>=MIN(B2, C2), A2<=MAX(B2, C2))

 

TRUE 및 FALSE 대신 사용자 고유의 값을 반환하려면 두 숫자 사이에 다음 Excel IF 문을 사용합니다.

=IF(AND(A2>MIN(B2, C2), A2<MAX(B2, C2)), "Yes", "No")

또는

=IF(AND(A2>=MIN(B2, C2), A2<=MAX(B2, C2)), "Yes", "No")

 

Excel 수식 : 두 날짜 사이 인 경우

Excel의 날짜 간 수식은 기본적으로 숫자 사이의 경우와 동일합니다.

주어진 날짜가 특정 범위 내에 있는지 확인하기 위해 일반 공식은 다음과 같습니다.

IF(AND(date >= start_date, date <= end_date), value_if_true, value_if_false)

경계 날짜를 포함하지 않음:

IF(AND(date > start_date, date < end_date), value_if_true, value_if_false)

그러나 주의할 점이 있습니다: IF는 인수에 직접 제공된 날짜를 인식하고 이를 텍스트 문자열로 간주합니다. IF가 날짜를 인식하려면 DATEVALUE 함수로 래핑해야 합니다.

 

예를 들어, A2의 날짜가 2022년 1월 1일과 2022년 12월 31일 사이인지 테스트하려면 다음 공식을 사용할 수 있습니다:

 

=IF(AND(A2>=DATEVALUE("1/1/2022"), A2<=DATEVALUE("12/31/2022")), "Yes", "No")

 

시작 날짜와 종료 날짜가 미리 정의 된 셀에있는 경우 수식이 훨씬 간단 해집니다.

=IF(AND(A2>=$E$2, A2<=$E$3), "Yes", "No")

 

여기서 $E$2는 시작일이고 $E$3은 종료일입니다. 절대 참조를 사용하여 셀 주소를 잠그면 아래 셀에 복사 할 때 수식이 깨지지 않습니다.

 

날짜가 다음 N일 이내인 경우

날짜가 오늘 날짜로부터 다음 n일 이내인지 테스트하려면 TODAY 함수를 사용하여 시작 날짜와 종료 날짜를 확인합니다. AND 문 내에서 첫 번째 논리 테스트는 대상 날짜가 오늘 날짜보다 큰지 확인하고, 두 번째 논리 테스트는 현재 날짜에 n일을 더한 날짜보다 작거나 같은지 확인합니다.

IF(AND(date > TODAY(), date <= TODAY()+n), value_if_true, value_if_false)

 

예를 들어, A2의 날짜가 다음 7일 이내에 발생하는지 테스트하기 위한 공식은 다음과 같습니다.

=IF(AND(A2>TODAY(), A2<=TODAY()+7), "Yes", "No")

 

날짜가 지난 N일 이내인 경우

지정된 날짜가 오늘 날짜의 마지막 n일 이내인지 테스트하려면 IF를 AND 및 TODAY 함수와 함께 다시 사용합니다. AND의 첫 번째 논리 테스트는 테스트된 날짜가 오늘 날짜에서 n일을 뺀 값보다 크거나 같은지 확인하고, 두 번째 논리 테스트는 날짜가 오늘보다 작은지 확인합니다.

IF(AND(date >= TODAY()-n, date < TODAY()), value_if_true, value_if_false)

 

예를 들어 A2의 날짜가 지난 7일 동안 발생했는지 확인하려면 공식은 다음과 같습니다.

=IF(AND(A2>=TODAY()-7, A2<TODAY()), "Yes", "No")